Aces High Bulletin Board

General Forums => Hardware and Software => Topic started by: LoneStarBuckeye on May 17, 2002, 10:36:20 AM

Title: Cougar Notes
Post by: LoneStarBuckeye on May 17, 2002, 10:36:20 AM

I thought I'd start a thread of interesting (at least to me) observations about the capabilities of the Cougar in Aces High.

1.  Toe Brakes.  I have recently reconfigured a gameport CH Pro Pedals rig so that it works as an analog rudder and left and right toe brakes.  There is a thread entitled "CH Pedals Pro" at the hardware forum at cougar.frugalsworld.com that discusses this and provides the pin-out of Cougar's rudder port.  

Before I had analog toe brakes, however, I wanted a way to simulate them.  Cougar's ability to digitally map analog axes and to simulate physically absent axes provided an intuitive way to accomplish this.  Basically, what I wanted is for the rudder offset to control the toe brakes when the brake key (I chose S4) is pressed.  The way I did this was to use the following statement to map regions on my rudder axis to logical variables:

RDDR 5 5 (0 20 40 60 80 100) /H X1 /H X2 ^ /H X3 /H X4

After that, I used those logical variables to "trim" the (nonexistent) toe brake axes in proportion to the rudder offset:

DEF X5 NOT S4
BTN X5 TRIM (TOEBRAKES,0%)  REM Brakes not applied
DEF X6 NOT (X1 OR X2 OR X3 OR X4) AND S4  REM Center
BTN X6 TRIM (TOEBRAKES,100%)
DEF X7 X2 AND S4 REM Mid-left brakes
BTN X7 TRIM (LBRK,100%) TRIM (RBRK,50%)
DEF X8 X1 AND S4 REM Full left brakes
BTN X8 TRIM (LBRK,100%) TRIM (RBRK,0%)
DEF X9 X3 AND S4 REM Mid-right brakes
BTN X9 TRIM (LBRK,50%) TRIM (RBRK,100%)
DEF X10 X4 AND S4 REM Full right brakes
BTN X10 TRIM (LBRK,0%) TRIM (RBRK,100%)

I used a scheme similar to the above and it worked great, but I have re-entered the code without checking it, so there may be syntax or logical errors.  Note that in order for this scheme to work, you must configure your axes in CCP so that AH can "see" the toe brake axes (check the box above the axis map).  Obviously, you can make the toebrake simulation less "granular" by defining more ranges on the RDDR axis, although doing so takes more logical variables.

2.  Analog Trim.  Cougar's ability to lock physical axes in combination with its ability to digitally map analog axes provides what I find an intuitive way to apply analog trim.  Basically, I assign a button (I use S4) to indicate "trim mode."  Once S4 is pressed, the joystick and rudder axes are locked in their current position and the control inputs are used to control analog trim.  When S4 is released, the axes are unlocked and control returns to normal.  I find this to be quite intuitive and it somewhat approximates having trim tabs on the stick.  I use something like the following code:

JOYX 5 3 (0 45 55 100) /H X1 ^ /H X2
JOYY 5 3 (0 45 55 100) /H X3 ^ /H X4
RDDR 5 3 (0 45 55 100) /H X5 ^ /H X6

REM -- Lock control axes at current value when S4 is pressed.
REM -- Unlock control axes when S4 is released
BTN S4 /P LOCK(JOYSTICK,LASTVALUE) LOCK(RDDR,LASTVALUE)
            /R UNLOCK(JOYSTICK) UNLOCK(RDDR)

REM -- Provide control inputs while S4 is pressed, as indicated
REM     by joystick and rudder inputs
DEF X7 S4 AND X1
BTN X7 /H trim:roll_left
DEF X8 S4 AND X2
BTN X8 /H trim:roll_right
DEF X9 S4 AND X3
BTN X9 /H trim:nose_up
DEF X10 S4 AND X4
BTN X10 /H trim:nose_down
DEF X11 S4 AND X5
BTN X11 /H trim:yaw_left
DEF X12 S4 AND X6
BTN X12 /H trim:yaw_right

Note:  If AH had analog trim axes like IL-2, when S4 is pressed, you could lock the control axes and SWAP the control axes and trim axes.  That would allow the joystick and rudder to control the analog trim axes.  When S4 is released, the axes could be SWAP'd back and UNLOCK'd.

3.  Axis response.  Cougar's CURVE statement allows the user to assign different axis resposne curves.  The Cougar profile that I load for AH and the profile within AH use "flat" curves for the joystick and rudder, and I have three different curves that I assign in the sim.  When the dogfight switch is in its "up" position, I use the most aggressive curve (dogfighting), and when the dogfight switch is in the lowest position, I use the least agressive curve (for landing).  The middle position on the dogfight switch loads, unsurprising, a medium-response curve:

CURVE /U (JOYY,-2) (JOYX,0) (RDDR,-2)
           /M (JOYY,-3) (JOYX,-1) (RDDR,-3)
           /D (JOYY,-4) (JOYX,-2) (RDDR,-4)

4. Combat scan.  I have defined several functions that I call "combat scans" that cycle through the various views quickly with a single keypress.  For example, I have a views:level_scan macro that cycles through the eight level views and a views:elevated_scan macro that cycles through the eight elevated views and the full up view.  I combine those two into a views:full_scan macro, which cycles through all of the level and elevated views, and a views:back_scan macro, which cycles through only the rear and three-quarters level and elevated views, along with the full up view).

I am interested to see what sorts of ideas you folks have regarding the Cougar and AH!

- JNOV

Title: Cougar Notes
Post by: Brent Stevens on May 17, 2002, 01:00:34 PM

Great post! Could I see how you did the scans?

Title: Cougar Notes
Post by: LoneStarBuckeye on May 17, 2002, 01:07:20 PM

Sure!  I sent you an e-mail, and if you reply with your e-mail address, I will send you my joystick and macro files.

- JNOV

Title: Cougar Notes
Post by: Brent Stevens on May 17, 2002, 01:16:10 PM

"You've got mail" :)

Title: Re: Cougar Notes
Post by: Zeb on May 19, 2002, 12:00:32 PM

Quote

Originally posted by LoneStarBuckeye

4. Combat scan.  I have defined several functions that I call "combat scans" that cycle through the various views quickly with a single keypress.  For example, I have a views:level_scan macro that cycles through the eight level views and a views:elevated_scan macro that cycles through the eight elevated views and the full up view.  I combine those two into a views:full_scan macro, which cycles through all of the level and elevated views, and a views:back_scan macro, which cycles through only the rear and three-quarters level and elevated views, along with the full up view).

I am interested to see what sorts of ideas you folks have regarding the Cougar and AH!

- JNOV [/B]

I am very interested in how you have implemented the Combat scan.  Can I have a copy of your Cougar profile to have a look at.  I have still only implemented a small portion of the Cougars capability in AH and am on the lookout for new ideas all the time.

I used the following for Flos's bombsight view

[color=808081]Rem ------------------------------------[/color]
[color=808081]Rem           In the Bombsight[/color]
[color=808081]Rem ------------------------------------[/color]


[color=0000FF]BTN T8 [/color][color=FF0000]/P /H [/color]Bomber_seat   Doors_Open Zoom Zoom_Default  Look_Down
             [color=FF0000]/R [/color]Doors_Open Zoom  Default_View

Title: Re: Re: Cougar Notes
Post by: Flossy on May 19, 2002, 12:59:05 PM

Quote

Originally posted by Zeb
I used the following for Flos's bombsight view

It works brilliantly too!  One quick flick of a switch and I am looking through the bombsite, zoom turned on and doors open - flick it back and the doors close, zoom is turned off and I am back in the pilot's seat - bombing is a breeze with this setup!  :D

Title: Cougar Notes
Post by: LoneStarBuckeye on May 19, 2002, 01:17:18 PM

Zeb:

Send me your e-mail address and I will send you a copy of my Cougar AH files.

- JNOV

Title: Cougar Notes
Post by: Zeb on May 19, 2002, 01:33:39 PM

Email address sent via here.....Thank's.

Title: Cougar Notes
Post by: Zeb on May 19, 2002, 02:27:24 PM

I have been thinking a bit more about your axis response notes JNOV in the post above.  I must admit I have gone straight from a CH stick to the Cougar and left the settings I had in AH well alone for now.  I had taylored the curves quite a bit for the CH sticks.  
When you say that you have set the AH curves as flat, do you mean all sliders to the top giving a straight 45 deg line bottom left to top right?  My original idea was to leave the Cougar curve at the default and trim for best feel with the AH axis curves.  My thoughts were that I would get more accurate reuslts this way.  But I am not sure now.  I am interested to know how other people have set the Cougar up in respect to the 3 axis curves.

Title: Cougar Notes
Post by: LoneStarBuckeye on May 19, 2002, 05:04:28 PM

Zeb:

When I say I set the AH curves flat, I do mean that I pushed all the sliders in the joystick menu to the top.  Doing so effecitvely passes through unchanged whatever input is received from the controllers.  Doing so simply provides a "blank slate" for tailoring the response curves in the Cougar.  You can use nonlinear curves in both the Cougar and in AH but the response is more difficult to anticipate than if you leave one or the other linear (i.e., flat).  The advantage of leaving the AH response curves linear and changing the response in the Cougar is that you can change the curves while flying.  As I stated above, I set up three different levels of responsiveness: one for dogfighting (most responsive), one for landing (least responsive), and a middle curve of median responsiveness.  An example of how to do this is:

CURVE /U (JOYY, -3) (JOYX,0) (RDDR,-2) Rem Most responsive
      /M (JOYY, -4) (JOYX,-1) (RDDR,-3) Rem Normal
      /D (JOYY, -5) (JOYX,-2) (RDDR,-4) Rem Least responsive

In the CURVE statement, a value of 0 (e.g., (JOYX,0)) causes the joystick to produce a flat (i.e., linear) output.  Positive values create increasingly responsive curves (i.e., curves that if viewed in the AH joystick profile editor would have the response curves above the reference line), and negative values (e.g., (JOYY,-3)) create increasingly non-responsive curves (i.e., curves that if viewed in the AH joystick profile editor would have responsive curves below the reference line).

- JNOV

Title: Cougar Notes
Post by: Brent Stevens on May 26, 2002, 01:40:23 PM

Any ideas how to pull trigger and get...
- press zoom key once then
- hold the fire key down (fire_both)
- then press the zoom key again when trigger is released to go back to normal view and not get any errors.

I tried /P and /R but view gets stuck in zoom after trigger release.

Rem --------------------------------------------
Rem   Weapon Control
Rem --------------------------------------------

DEF X5 TG1 AND NOT S3
DEF X6 TG1 AND S3

BTN X5 /P sight:zoom /H wep:fire_both /R sight:zoom
BTN X6 misc:film_record
================================

Title: Cougar Notes
Post by: LoneStarBuckeye on May 26, 2002, 02:42:18 PM

Brent:

I think the problem is with your placement of the "/H."  Try this:

Rem --------------------------------------------
Rem Weapon Control
Rem --------------------------------------------

DEF X5 TG1 AND NOT S3
DEF X6 TG1 AND S3

BTN X5 /P sight:zoom KD(wep:fire_both) /R sight:zoom KU(wep:fire_both)
BTN X6 misc:film_record

KD means "key down" and KU means "key up."  Those commands give you more precise control over keypresses.  I think that what I suggest should simulate pressing the wep:fire_both key when TG1 (unshifted) is pressed and holding it down until TG1 (unshifted) is released.

I tested the code in Foxy's keypress tester application and it seems to work as intended.

- JNOV

Title: Cougar Notes
Post by: Brent Stevens on May 26, 2002, 03:11:01 PM

Works like a champ Professor :)
TY